電腦已經(jīng)安裝Windows10的系統(tǒng)，且通過(guò)不同方法，激活了系統(tǒng)，如何查詢(xún)已激活Windows10系統(tǒng)的密鑰呢?下面就讓學(xué)習(xí)啦小編教大家如何用命令查看系統(tǒng)激活密鑰。

　　用命令查看系統(tǒng)激活密鑰的方法

　　制作一個(gè)【密鑰查詢(xún).vbs】文件可以查詢(xún)已激活系統(tǒng)的密鑰及備份密鑰。

　　把下面的內(nèi)容復(fù)制到記事本中：

　　————————————————————————————————

　　Option Explicit

　　Dim objshell,path,DigitalID, Result

　　Set objshell = CreateObject("WScript.Shell")

　　'Set registry key path

　　Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"

　　'Registry key value

　　DigitalID = objshell.RegRead(Path & "DigitalProductId")

　　Dim ProductName,ProductID,ProductKey,ProductData

　　'Get ProductName, ProductID, ProductKey

　　ProductName = "系統(tǒng)名稱(chēng)：" & objshell.RegRead(Path & "ProductName")

　　ProductID = "產(chǎn)品ID：" & objshell.RegRead(Path & "ProductID")

　　ProductKey = "已安裝密鑰：" & ConvertToKey(DigitalID)

　　ProductData = ProductName & vbNewLine & ProductID & vbNewLine & ProductKey

　　'Show messbox if save to a file

　　If vbYes = MsgBox(ProductData & vblf & vblf & "要將密鑰保存到文件嗎?", vbYesNo + vbQuestion, "軟媒魔方備份Windows密鑰信息") then

　　Save ProductData

　　End If

　　'Convert binary to chars

　　Function ConvertToKey(Key)

　　Const KeyOffset = 52

　　Dim isWin10, Maps, i, j, Current, KeyOutput, Last, keypart1, insert

　　'Check if OS is Windows 10

　　isWin10 = (Key(66) \ 6) And 1

　　Key(66) = (Key(66) And &HF7) Or ((isWin10 And 2) * 4)

　　i = 24

　　Maps = "BCDFGHJKMPQRTVWXY2346789"

　　Do

　　Current= 0

　　j = 14

　　Do

　　Current = Current* 256

　　Current = Key(j + KeyOffset) + Current

　　Key(j + KeyOffset) = (Current \ 24)

　　Current=Current Mod 24

　　j = j -1

　　Loop While j >= 0

　　i = i -1

　　KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput

　　Last = Current

　　Loop While i >= 0

　　If (isWin10 = 1) Then

　　keypart1 = Mid(KeyOutput, 2, Last)

　　insert = "N"

　　KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)

　　If Last = 0 Then KeyOutput = insert & KeyOutput

　　End If

　　ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)

　　End Function

　　'Save data to a file

　　Function Save(Data)

　　Dim fso, fName, txt,objshell,UserName

　　Set objshell = CreateObject("wscript.shell")

　　'Get current user name

　　UserName = objshell.ExpandEnvironmentStrings("%UserName%")

　　'Create a text file on desktop

　　fName = "C:\Users\" & UserName & "\Desktop\Windows密鑰備份.txt"

　　Set fso = CreateObject("Scripting.FileSystemObject")

　　Set txt = fso.CreateTextFile(fName)

　　txt.Writeline Data

　　txt.Close

　　End Function

　　————————————————————————————————

　　點(diǎn)擊記事本左下角的【文件】，在下拉菜單中點(diǎn)擊【另存為】;

　　在打開(kāi)的另存為窗口，點(diǎn)擊【桌面】，在文件名(N)欄中輸入：密鑰查詢(xún).vbs，再點(diǎn)擊：保存;

　　我們保存密鑰查詢(xún).vbs文件后，在系統(tǒng)桌面上顯示一個(gè)【密鑰查詢(xún).vbs】文件圖標(biāo)，左鍵雙擊【密鑰查詢(xún).vbs】文件圖標(biāo)，打開(kāi)一個(gè)軟媒魔方備份Windows密鑰信息對(duì)話框，顯示了系統(tǒng)名稱(chēng)、產(chǎn)品ID和已安裝密鑰。

　　如果需要保存安裝密鑰，點(diǎn)擊：是(Y)，則安裝密鑰就會(huì)以記事本的方式保存到系統(tǒng)桌面上。